H*****************************************************************                                                                                                                     
     H* メール送信サンプルプログラム                                    *                                                                                                                     
     H*    /MAIL/MSG.TXTを下記宛先に送信するサンプルです。              *                                                                                                                     
     H*         FROM SUPPORT@HRM.CO.JP                                *                                                                                                                     
     H*         TO   HRM@HRM.CO.JP                                    *                                                                                                                     
     H*              SE-SUPPORT@DOCOMO.NE.JP                          *                                                                                                                     
     H*****************************************************************                                                                                                                     
     H DATEDIT(*YMD)                                                                                                                                                                        
     D*****************************************************************                                                                                                                     
     D* 宛先テーブル                                                                                                                                                                      
     D*****************************************************************                                                                                                                     
     D T1              S             30    DIM(2)  CTDATA PERRCD(1)             宛先                                                                                                      
     D*****************************************************************                                                                                                                     
     D* QtmmSendMailのパラメータ                                    *                                                                                                                     
     D*****************************************************************                                                                                                                     
     DSENDMAIL         C                   'QtmmSendMail'                       QtmmSendMail                                                                                                
     D*                                                                                                                                                                                     
     DFOLDER           S            256                                                                                                                                                     
     DFOLDERLEN        S              9B 0                                                                                                                                                  
     DFROMADDR         S            256                                                                                                                                                     
     DFROMADDRLEN      S              9B 0                                                                                                                                                  
     D*                                                                                                                                                                                     
     DMIME             DS                                                                                                                                                                   
     D OFFSET                  1      4B 0                                                                                                                                                  
     D TOADDRLEN               5      8B 0                                                                                                                                                  
     D FORMAT                  9     16A   INZ('ADDT0100')                                                                                                                                  
     D DISTTYPE               17     20B 0                                                                                                                                                  
     D RESERVED               21     24B 0 INZ(0)                                                                                                                                           
     D TOADDR                 25    150A                                                                                                                                                    
     D*                                                                                                                                                                                     
     DTOADDRKEN        S              9B 0                                                                                                                                                  
     DERRORMSG         S            256A                                                                                                                                                    
     D*                                                                                                                                                                                     
     DMIMEALL          S            150A   DIM(50)                              MAX50件                                                                                                   
     D*                                                                                                                                                                                     
     C**t**************************************************************                                                                                                                     
     C*メインルーチン                                               *                                                                                                                     
     C*****************************************************************                                                                                                                     
     C                   EVAL      FOLDER   = '/MAIL/MSG.TXT'                   ファイル名                                                                                                
     C                   EVAL      FOLDERLEN = %LEN(%TRIM(FOLDER))              ファイル名長さ                                                                                            
     C                   EVAL      FROMADDR = 'SUPPORT@HRM.CO.JP'               送信元                                                                                                    
     C                   EVAL      FROMADDRLEN = %LEN(%TRIM(FROMADDR))          送信元長さ                                                                                                
     C*                                                                                                                                                                                     
     C     1             DO        2             I1                5 0                                                                                                                      
     C                   CLEAR                   DISTTYPE                                                                                                                                   
     C                   CLEAR                   TOADDR                                                                                                                                     
     C*                                                                                                                                                                                     
     C                   EVAL      TOADDR = T1(I1)                                                                                                                                          
     C                   EVAL      DISTTYPE = 1                                 配布タイプCC                                                                                              
     C                   IF        I1 = 1                                                                                                                                                   
     C                   EVAL      DISTTYPE = 0                                 配布タイプ通常                                                                                            
     C                   ENDIF                                                                                                                                                              
     C                   EVAL      TOADDRLEN = %LEN(%TRIM(TOADDR))              ファイル名長さ                                                                                            
     C                   EVAL      OFFSET = %SIZE(MIME)                                                                                                                                     
     C*                                                                                                                                                                                     
     C                   EVAL      MIMEALL(I1) = MIME                                                                                                                                       
     C*                                                                                                                                                                                     
     C                   ENDDO                                                                                                                                                              
     C*                                                                                                                                                                                     
     C                   EVAL      TOADDRKEN = I1 - 1                                                                                                                                       
     C*                                                                                                                                                                                     
     C* QtmmSendMailの呼出                                                                                                                                                                
     C                   CALLB     SENDMAIL                                                                                                                                                 
     C                   PARM                    FOLDER                         ファイル名                                                                                                
     C                   PARM                    FOLDERLEN                      ファイル名の長さ                                                                                          
     C                   PARM                    FROMADDR                       発信元アドレス (SMTP)                                                                                     
     C                   PARM                    FROMADDRLEN                    発信元の長さ                                                                                              
     C                   PARM                    MIMEALL                        第１宛先アドレス (SMTP)                                                                                   
     C                   PARM                    TOADDRKEN                      宛先の総数                                                                                                
     C                   PARM                    ERRORMSG                       エラー・コード                                                                                            
     C*                                                                                                                                                                                     
     C                   SETON                                        LR                                                                                                                    
     C                   RETURN                                                                                                                                                             
     C*****************************************************************                                                                                                                     
**                                                                                                                                                                                          
HRM@HRM.CO.JP                                                                                                                                                                               
SE-SUPPORT@DOCOMO.NE.JP